Last Upated:

March 22, 2025

Overview:

This project is a relay-based true bypass system for guitar pedals, built around an Arduino microcontroller and inspired by the Incandenza Bypass by Demedash Effects, with functionality modeled after Earthquaker Devices’ Flexi-Switch system. The soft-touch footswitch logic was further informed and inspired by MAS Effects’ relay bypass system, but unlike previous examples, this design uses a user-programmed Arduino as the control brain—offering flexibility, custom LED control, and easily modifiable switching logic.

The system allows a momentary soft-touch footswitch to toggle a relay, which in turn switches the signal path between true bypass (direct from input to output) and effect mode (routing through the pedal circuit). This is accomplished using a DPDT relay controlled via an NPN transistor, with power supplied either from the Arduino’s onboard 5V regulator or a dedicated 5V regulator (via 7809 and L7805 as shown on the schematic).

The sketch includes logic for both toggle (tap) and momentary (hold) functions. While the current implementation uses D7 to trigger the relay, the user may reroute control logic to D2 or other pins for more complex behavior (e.g., MIDI, tempo-synced switching, or multi-effect control). Code and layout are modular, allowing future integration with multi-relay routing, tap tempo, or expression pedal switching.

This project is a flexible, Arduino-based true bypass system that brings high-end pedal switching logic into the hands of DIY builders. It preserves tone with mechanical true bypass, adds soft-touch relay switching, and can be modified with just a few lines of code. The design combines compact hardware (Nano), protective electronics, and clear signal routing.

Technical Information:

• 5 Volt Relay: Acts as a DPDT switch to handle guitar signal routing. Two poles allow signal input to be rerouted from bypass to FX send, and from FX return back to output. The relay coil is energized by sinking current through a 2N2222 NPN transistor controlled by Arduino pin D7.

• Transistor and Base Resistor: A 220 ohm resistor limits current to the transistor base, ensuring that the Arduino does not exceed its 40mA per pin rating while still saturating the transistor for reliable relay switching. Q1 (2N2222) controls the relay’s ground path, acting as a low-side switch.

• Flyback Diode (1N4007): Placed across the relay coil to suppress high-voltage spikes when the relay turns off, preventing damage to the transistor and Arduino.

• LED Indicator: Controlled in software but wired to relay logic so users can tie it directly to D7 or leave it as programmable. A 4.7k ohm resistor limits current to the status LED (D1). An LED indicator can also be added to the Arduino board by connecting an LED from D6 to a current limiting resistor to ground. The schematic does NOT include the Arduino-based LED indicator, but the code does include this functionality.

• Footswitch (SW1): A normally open, momentary soft-touch switch, connected to GND and read by the Arduino via D2. When pressed, the Arduino uses logic to determine whether the press is momentary or a toggle, allowing both momentary and latching modes.

• Two power options are outlined:

  1. Shared 5V Supply (left side of schematic): The Arduino and relay are powered from the same 5V source (e.g., a 9V supply stepped down via Arduino’s onboard regulator).

  2. Isolated Relay Supply (right side of schematic): If using a supply greater than 12V, the relay can be powered by an external 5V regulator (e.g., L7805) with isolation from the Arduino, offering cleaner switching and preventing voltage sag.

• Signal Path (DPDT Switching): COM1 (pin 11) receives the guitar signal. NO1 (pin 9) sends the signal to the FX input when the relay is active. COM2 (pin 6) receives the FX return. NO2 (pin 4) passes the FX output to the amplifier. NC1 and NC2 are tied together to create a bypass path when the relay is OFF, routing the signal directly from input to output. This layout mimics the Incandenza Bypass’s mechanical function, but with digital control, silent switching, and the option to integrate LED indicators and advanced logic.

Development Notes:

• Blog Part One

• Blog Part Two

• Blog Part Three

Demonstration Video:

Code (or Sketch):

const int relayPin = 7;   // Pin for relay (via transistor)
const int buttonPin = 2;  // Pin for button
const int ledPin = 6;     // Pin for LED indicator

bool relayState = false;  // Tracks relay state
bool lastButtonState = HIGH;  
unsigned long buttonPressTime = 0;
const int holdThreshold = 250;  // Hold duration in milliseconds

void setup() {
  pinMode(relayPin, OUTPUT);
  pinMode(ledPin, OUTPUT);
  pinMode(buttonPin, INPUT_PULLUP);
}

void loop() {
  bool buttonState = digitalRead(buttonPin);

  // Button Press Detected (Falling Edge)
  if (buttonState == LOW && lastButtonState == HIGH) {
    buttonPressTime = millis();  // Record when button is pressed
  }

  // Button Released (Rising Edge)
  if (buttonState == HIGH && lastButtonState == LOW) {
    unsigned long pressDuration = millis() - buttonPressTime;

    if (pressDuration < holdThreshold) {
      // Short Press: Toggle Relay
      relayState = !relayState;
    } else {
      // Long Press: Ensure Relay Turns Off on Release
      relayState = false;
    }
    digitalWrite(relayPin, relayState);
    digitalWrite(ledPin, relayState);  // Update LED state
  }

  // While Holding the Button, Relay Stays ON and LED Blinks
  if (buttonState == LOW && (millis() - buttonPressTime) > holdThreshold) {
    digitalWrite(relayPin, HIGH);
    
    // Blink LED every 100ms to indicate "Hold Mode." User can edit this so LED stays on while in MOM mode.
    if ((millis() / 100) % 2 == 0) {
      digitalWrite(ledPin, HIGH);
    } else {
      digitalWrite(ledPin, LOW);
    }
  } else {
    digitalWrite(ledPin, relayState); // LED matches relay state (ON/OFF)
  }

  lastButtonState = buttonState;  // Update button state
}

Stripboard Layout (unverified):

Bill of Materials

• Q1: NPN transistor, preferably 2N2222, a common NPN bipolar junction transistor (BJT)

• D1: 1N4007

• D2: Indicator LED

• 5V DPDT Relay (above schematic is a non-miniature relay)

• RLED: 480 ohms to 4.7k ohms, depending on user’s preferred brightness

• R1: 220 ohms to 480 ohms, anything above may cause D7 to fail to trigger Q1

Sources:

• Incandenza Bypass

• Earthquaker Devices Flexi-Switching

• MAS Effects Relay Bypass

• Connecting a Relay Module to a Microcontroller by Brad Henson (YT)